SPSS code for RELTRAD:

* The following codes Jacobite Apostolics as Orthodox-Christian in GSS categorization
IF (other eq 183) relig=10.

* The following code breaks down religious groups by Protestant, Catholic,
* etc.

COMPUTE xaffil = 0 .
IF (relig eq 1) xaffil = 1.
IF any(relig,11,13) xaffil = 1.
IF (relig eq 2) xaffil = 4.
IF (relig eq 3) xaffil = 5.
IF (relig eq 4) xaffil = 9.
IF (relig eq 5) xaffil = 6.
IF any(relig,6,7,8,9,10,12) xaffil = 6.
VALUE LABELS xaffil 1 ‘prot’ 4 ‘cath’ 5 ‘jew’ 6 ‘other’ 9 ‘nonaf’.

* The following code breaks down religious groups by evangelicals, black
* Protestants, mainline, liberal and conservative nontraditional,
* and Protestant nondenomination/no denomination.

compute xbp = 0.

* Following are black sectarians.

IF any(other,7,14,15,21,37,38,56,78,79,85,86,87,88,98,103,104,128,133, 151, 168, 169, 175,
179, 186) xbp = 1.

* Following are historically black churches.

IF (denom=12 or denom=13 or denom=20 or denom=21) xbp = 1.

* Following are black Methodists (e.g., AME).

IF ((denom=23 or denom=28) and race = 2) xbp=1.

* Following are black Baptists.

IF ((denom=18 or denom=15 or denom=10 or denom=11 or denom=14) and
race=2) xbp = 1.
IF (other=93 and race=2) xbp = 1.

* Evangelicals.
compute xev = 0.

* Following two commands put sectarians into evangelical.

IF any(other,2,3,5,6,9,10,12,13,16,18,20, 22,26,27,
28,32,34,35,36,39,42,43,45,47,51,52,53,55,57,63,65,66,67,68,69,
76,77,83,84,90,91,92,94,97,100,101,102,106,107,108,109,
110,111,112,115,117,118,120,121,125,127,129,131,132,134,135, 137,
138,139,140, 143, 144, 146, 154, 155, 156, 158, 159, 165, 167, 170,171,172, 173,
174,176,177,178,180, 181, 182, 184, 185, 187, 191, 198, 201, 205, 207) xev = 1.

IF any(other,24,31,41 ,122,124) xev = 1.

* Following puts conservative Methodists into evangelical.
IF ((denom=23) and race ne 2) xev=1.

* Following puts conservative Lutherans into evangelical.
IF any(denom,32,33,34) xev = 1.

* Following puts conservative Presbyterians into evangelical.
IF (denom=42) xev=1.

* Following puts white conservative Baptists into evangelical.
IF ((denom=18 or denom=15 or denom=10 or denom=14) and
race ne 2) xev = 1.
IF (other=93 and race ne 2) xev=1.

* A few black protestants overlapped with evangelical. So we removed them from
* evangelical.
IF (xbp=1) xev=0.

*Mainline Protestants.
compute xml = 0.
IF any(other,1,8,19,23,25,40,44,46,48,49,50,54,70,71,72,73,81,89,96,99,105,119, 148, 150,
153,160, 166, 188) xml = 1.
IF any(denom,22,30,31,35,38,40,41,43,48,50) xml = 1.

* Following are white generic Methodists into mainline.
IF ((denom=28) and race ne 2) xml=1.

* Following are white American Baptist USA into mainline.
IF ((denom=11) and race ne 2) xml=1.

* Catholics.
compute xcath = 0.
IF any(other,123, 126, 149) xcath = 1.
IF (xaffil=4) xcath = 1.

* Jews.
compute xjew = 0.
IF (xaffil=5) xjew = 1.

* Adherents of other religions.
compute xother = 0.
IF (xaffil=6 and xev ne 1) xother = 1.

* Following puts conservative nontraditionals into other.
IF any(other,33,58,59,60,61,62,64,113, 114, 116, 130,145, 157, 162, 206) xother = 1.

* Following puts liberal nontraditionals into other.
IF any(other,11,17,29,30,74,75,80,82,95,136,141, 142, 152, 163, 164) xother = 1.

* Unaffiliateds/Nonaffiliateds.
compute xnonaf = 0.
IF (xaffil=9) xnonaf = 1.

* NOTE: THE FOLLOWING DEALS WITH NO-DENOM AND
* NON-DENOM PROTESTANTS.
compute xprotdk = 0.
IF (denom=70) xprotdk = 1.

* Following removes no-denoms/non-denoms who attend less than once a month
* and puts those who attend more in evangelical.
DO IF (attend>3 and attend ne 9).
compute xprotdk2=xprotdk.
END IF.
If (xprotdk2=1) xev = 1.

* Following does RELTRAD.
compute reltrad = 0.

*Following drops responses that could not be accurately placed according to information *in the GSS

IF any(other, 161, 185, 191,198,205) reltrad=0.
IF (xev = 1) reltrad = 1.
IF (xml = 1) reltrad = 2.
IF (xbp = 1) reltrad = 3.
IF (xcath = 1) reltrad = 4.
IF (xjew = 1) reltrad = 5.
IF (xother = 1) reltrad = 6.
IF (xnonaf = 1) reltrad = 7.

RECODE
reltrad (0=SYSMIS) .
value labels reltrad 1 ‘evangelical’
2 ‘mainline’
3 ‘black protestant’
4 ‘catholic’
5 ‘jewish’
6 ‘other faith’
7 ‘nonaffiliated’.
execute.